EB - Barometric Pressure Sensor

$9.95

  • Model: EB0201310B
  • Shipping Weight: 3gram
  • 9998 Units in Stock

Add to Cart:



Item specifics

Brand Name:Maker Studio

Product Description

Electronic Brick - Barometric Pressure Sensor (BMP085) features a measuring range of anywhere between 30,000 and 110,000 Pa (Pascal unit). It also provides a temperature measurement from 0 to 65 degree centigrade.

 

Features

  • Working Voltage: 3.3V
  • Supply Current: 5uA (650uA during conversion)
  • Operating Range: 30,000 ~ 110,000Pa
  • Operating Temperature: -25 ~ +85degree centigrade
  • Resolution of output data: 1Pa, 0.1degree centigrade
  • I2C Interface
  • With Makerduino Demo Code
  • With Power Light and Signal Light
  • Weight: 3g

 

Applications

  • Barometric pressure detector
  • Weather detector
  • Altitude above sea level detector

Details

SDA and SCL are the I2C communication lines. SDA being where the data is transmitted, and SCL is the clock that keeps track of that data. XCLR acts as a master reset. It's active-low, so if it's pulled to GND it will reset the BMP085 and set its registers to their default state. EOC(end of conversion) is a signal generated by the BMP085 that's triggered whenever a pressure or temperature conversion has finished. XCLR and EOC are optional, and if you don't need to use them you can just leave them unconnected.

aeProduct.getSubject()

Use with Makerduino

The following steps show how to use EB - Barometric Pressure Sensor with Makerduino.

Materials

  • Makerduino
  • Electronic Brick Shield
  • EB - Barometric Pressure Sensor
  • A/B type USB cable
  • Female DuPont wires

Steps

1. Connect Electronic Brick Shield onto Makerduino to bring out all the Makerduino Pins.

aeProduct.getSubject()

 

2. Connect EB - Barometric Pressure Sensor to Makerduino as following.

aeProduct.getSubject()

 

3. Connect the Makerduino to Computer by the USB cable.

 

4. Download the Makerduino demo code EB - Barometric Pressure Sensor.zip. Unzip the code directly into the libraries floder.

 

5. Open Makerduino IDE, choose the right Board and Serial Port. Open the sketch EB_ BarometricPressureSensor.ino and upload it to the Makerduino.

The following is the demo code for EB - Barometric Pressure Sensor. (Note: It could be a little different from the code file downloaded. Please follow the downloaded file.)

 

/*

  Get pressure and temperature from the EB_BarometricPressureSensor and calculate

  altitude. Serial.print it out at 9600 baud to serial monitor.

 

  I've heard folks may be encountering issues with this code,

  who're running a Makerduino at 8MHz. If you're using a Makerduino

  Pro 3.3V/8MHz, or the like, you may need to increase some of

  the delays in the bmp085ReadUP and bmp085ReadUT functions.

*/

 

#include <Wire.h>

 

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

 

const unsigned char OSS = 0;  // Oversampling Setting

 

// Calibration values

int ac1;

int ac2;

int ac3;

unsigned int ac4;

unsigned int ac5;

unsigned int ac6;

int b1;

int b2;

int mb;

int mc;

int md;

 

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)

// so ...Temperature(...) must be called before ...Pressure(...).

long b5;

 

short temperature;

long pressure;

 

// Use these for altitude conversions

const float p0 = 101325;     // Pressure at sea level (Pa)

float altitude;

const float currentAltitude = 8;

 

// your current altitude above sea level in METERS

// you can get the data from google earth

 

const float ePressure = p0 * pow((1-currentAltitude/44330), 5.255); 

// expected pressure (in Pa) at altitude

float weatherDiff;

void setup()

{

  Serial.begin(9600);

  Wire.begin();

  bmp085Calibration();

}

 

void loop()

{

  temperature = bmp085GetTemperature(bmp085ReadUT());

  pressure = bmp085GetPressure(bmp085ReadUP());

  altitude = (float)44330 * (1 - pow(((float) pressure/p0), 0.190295));

    weatherDiff = pressure - ePressure;

  if(weatherDiff > 250)

    Serial.println("Sunny!");

  else if ((weatherDiff <= 250) || (weatherDiff >= -250))

    Serial.println("Partly Cloudy");

  else if (weatherDiff > -250)

    Serial.println("Rain :-(");

  Serial.println();

 

  Serial.print("Temperature: ");

  Serial.print(temperature, DEC);

  Serial.println(" *0.1 deg C");

  Serial.print("Pressure: ");

  Serial.print(pressure, DEC);

  Serial.println(" Pa");

  Serial.print("Altitude: ");

  Serial.print(altitude, 2);

  Serial.println(" m");

  Serial.println();

 

  delay(1000);

}

 

// Stores all of the bmp085's calibration values into global variables

// Calibration values are required to calculate temp and pressure

// This function should be called at the beginning of the program

void bmp085Calibration()

{

  ac1 = bmp085ReadInt(0xAA);

  ac2 = bmp085ReadInt(0xAC);

  ac3 = bmp085ReadInt(0xAE);

  ac4 = bmp085ReadInt(0xB0);

  ac5 = bmp085ReadInt(0xB2);

  ac6 = bmp085ReadInt(0xB4);

  b1 = bmp085ReadInt(0xB6);

  b2 = bmp085ReadInt(0xB8);

  mb = bmp085ReadInt(0xBA);

  mc = bmp085ReadInt(0xBC);

  md = bmp085ReadInt(0xBE);

}

 

// Calculate temperature given ut.

// Value returned will be in units of 0.1 deg C

short bmp085GetTemperature(unsigned int ut)

{

  long x1, x2;

 

  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;

  x2 = ((long)mc << 11)/(x1 + md);

  b5 = x1 + x2;

 

  return ((b5 + 8)>>4); 

}

 

// Calculate pressure given up

// calibration values must be known

// b5 is also required so bmp085GetTemperature(...) must be called first.

// Value returned will be pressure in units of Pa.

long bmp085GetPressure(unsigned long up)

{

  long x1, x2, x3, b3, b6, p;

  unsigned long b4, b7;

 

  b6 = b5 - 4000;

  // Calculate B3

  x1 = (b2 * (b6 * b6)>>12)>>11;

  x2 = (ac2 * b6)>>11;

  x3 = x1 + x2;

  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

 

  // Calculate B4

  x1 = (ac3 * b6)>>13;

  x2 = (b1 * ((b6 * b6)>>12))>>16;

  x3 = ((x1 + x2) + 2)>>2;

  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

 

  b7 = ((unsigned long)(up - b3) * (50000>>OSS));

  if (b7 < 0x80000000)

    p = (b7<<1)/b4;

  else

    p = (b7/b4)<<1;

   

  x1 = (p>>8) * (p>>8);

  x1 = (x1 * 3038)>>16;

  x2 = (-7357 * p)>>16;

  p += (x1 + x2 + 3791)>>4;

 

  return p;

}

 

// Read 1 byte from the BMP085 at 'address'

char bmp085Read(unsigned char address)

{

  unsigned char data;

 

  Wire.beginTransmission(BMP085_ADDRESS);

  Wire.write(address);

  Wire.endTransmission();

 

  Wire.requestFrom(BMP085_ADDRESS, 1);

  while(!Wire.available())

    ;

   

  return Wire.read();

}

 

// Read 2 bytes from the BMP085

// First byte will be from 'address'

// Second byte will be from 'address'+1

int bmp085ReadInt(unsigned char address)

{

  unsigned char msb, lsb;

 

  Wire.beginTransmission(BMP085_ADDRESS);

  Wire.write(address);

  Wire.endTransmission();

 

  Wire.requestFrom(BMP085_ADDRESS, 2);

  while(Wire.available()<2)

    ;

  msb = Wire.read();

  lsb = Wire.read();

 

  return (int) msb<<8 | lsb;

}

 

// Read the uncompensated temperature value

unsigned int bmp085ReadUT()

{

  unsigned int ut;

 

  // Write 0x2E into Register 0xF4

  // This requests a temperature reading

  Wire.beginTransmission(BMP085_ADDRESS);

  Wire.write(0xF4);

  Wire.write(0x2E);

  Wire.endTransmission();

 

  // Wait at least 4.5ms

  delay(5);

 

  // Read two bytes from registers 0xF6 and 0xF7

  ut = bmp085ReadInt(0xF6);

  return ut;

}

 

// Read the uncompensated pressure value

unsigned long bmp085ReadUP()

{

  unsigned char msb, lsb, xlsb;

  unsigned long up = 0;

 

  // Write 0x34+(OSS<<6) into register 0xF4

  // Request a pressure reading w/ oversampling setting

  Wire.beginTransmission(BMP085_ADDRESS);

  Wire.write(0xF4);

  Wire.write(0x34 + (OSS<<6));

  Wire.endTransmission();

 

  // Wait for conversion, delay time dependent on OSS

  delay(2 + (3<<OSS));

 

  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)

  Wire.beginTransmission(BMP085_ADDRESS);

  Wire.write(0xF6);

  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 3);

 

  // Wait for data to become available

  while(Wire.available() < 3)

    ;

  msb = Wire.read();

  lsb = Wire.read();

  xlsb = Wire.read();

 

  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

 

  return up;

}

 

6.  Check the Results. After the sketch is successfully uploaded, let's open the Serial Monitor. The Serial Monitor displays information as following. When change the position, the detected result of pressure and altitude change as well.     

aeProduct.getSubject()

Download information

https://drive.google.com/?usp=folder&authuser=0&usp=folder#folders/0BzxrU4QvH7jEd3ZJTVdnNUpXNVE

Find EB - Barometric Pressure Sensor.zip to download schematic and other material.

 

 

 

 

about us 02

This product was added to our catalog on Tuesday 11 February, 2014.

Your IP Address is: 23.20.60.138
Copyright © 2017 Maker Studio